【ライブラリ管理を効率化！】JavaプロジェクトでのBOMの生成・利用方法の解説

plugins {
    // bom生成に必要なプラグイン
    id 'java-platform'
    id 'maven-publish'
}

group = 'hirabay.bom'
version = '0.0.1'

javaPlatform {
    allowDependencies()
}

repositories {
    mavenCentral()
}

dependencies {
    // constraintsでくくるとbom利用者側でversion指定がいらなくなる
    // ライブラリを使用していない場合は何も起きない（勝手にライブラリが追加されたりしない）
    constraints {
        api 'org.mybatis.spring.boot:mybatis-spring-boot-starter:3.0.2'
        api 'org.mybatis.spring.boot:mybatis-spring-boot-starter-test:3.0.2'
    }

    // bomの中にbomを含めることも可能
    api platform('org.springframework.boot:spring-boot-dependencies:3.0.8')
    api platform('org.springframework.cloud:spring-cloud-dependencies:2022.0.3')
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            group = 'hirabay.bom' // 未指定の場合、プロジェクトのgroupを使用
            artifactId = 'sample-bom' // 未指定の場合、プロジェクト名を使用
            version = '0.0.1'  // 未指定の場合、プロジェクトのversionを使用
            from components.javaPlatform
        }
    }
}

ext {
    // ライブラリのversionをmap形式で定義（keyはSpringBootのminor version）
    versionMap = [
            'org.mybatis.spring.boot:mybatis-spring-boot-starter': [
                    '2.7': '2.2.+',
                    '3.0': '3.0.+'
            ],
            'org.mybatis.spring.boot:mybatis-spring-boot-starter-test': [
                    '2.7': '2.2.+',
                    '3.0': '3.0.+'
            ],
    ]
    // bomのversionをmap形式で定義（keyはSpringBootのminor version）
    bomVersionMap = [
            'org.springframework.boot:spring-boot-dependencies': [
                    '2.7': '2.7.+',
                    '3.0': '3.0.+'
            ],
            'org.springframework.cloud:spring-cloud-dependencies': [
                    '2.7': '2021.0.+',
                    '3.0': '2022.0.+'
            ],
    ]
}

dependencies {
    constraints {
        // mapからライブラリを展開
        // SpringBootに依存しないライブラリを利用する場合を考慮し、
        // 「*」を指定するとminor versionに関係なく組み込み可能にしておく
        for (lib in versionMap.keySet()) {
            if (versionMap[lib]['*'] != null) {
                api "${lib}:${versionMap[lib]['*']}"
            } else if (versionMap[lib][springBootVersion] != null) {
                api "${lib}:${versionMap[lib][springBootVersion]}"
            }
        }
    }

    // mapからbomを展開
    // SpringBootに依存しないbomを利用する場合を考慮し、
    // 「*」を指定するとminor versionに関係なく組み込み可能にしておく
    for (bom in bomVersionMap.keySet()) {
        if (bomVersionMap[bom]['*'] != null) {
            api platform("${bom}:${bomVersionMap[bom]['*']}")
        } else if (bomVersionMap[bom][springBootVersion] != null) {
            api platform("${bom}:${bomVersionMap[bom][springBootVersion]}")
        }
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            group = 'hirabay.bom'
            artifactId = 'sample-bom'

            // versionを日時を使って自動で生成
            def date = new Date()
            def format = new SimpleDateFormat("yyyyMMddHHmmss")
            version = "${springBootVersion}.${format.format(date)}"

            from components.javaPlatform
        }
    }
}

springBootVersion=3.0

$ ./gradlew publish -PspringBootVersion=2.7

$ ./gradlew publish -PspringBootVersion=3.0